知道WSH吗?不知道吧!这也难怪,微软推出了WSH,却不推出相关的书籍、文档、联机帮助,也难怪你不知道。
  WSH的全称是“Windows Scripting Host”,是一种使用脚本语言实现系统功能的小工具,不妨当作批处理来理解吧。不过WSH比起批处理来可就强多了,它的许多功能是批处理无法实现的。
  关于WSH的资料真是难找极了,我就根本找不到。自己瞎闯乱撞,好不容易才找到了一点点窍门,与大家分享。如果你发现了什么,一定要告诉我呀!
  先看个简单的小例子吧!
message="今天是"
message=message & Year(Date) & "年"
message=message & Month(Date) & "月"
message=message & Day(Date) & "日。"

curHour=Hour(Time)
if curHour<6 then
    message=message & chr(13) & chr(10) & "还不睡觉?已经很晚了,你知道吗?"
end if

MsgBox message,vbInformation,"脚本"
  将这些代码贴到“记事本”里,保存为“test.vbs”。当然,你可以取任意别的名字,不过一定要带上.vbs。保存时最好加上半角引号,像这样"test.vbs"。否则有的记事本有时会将它存成“test.vbs.txt”,那就无法使用了。存好后应该看到这样的图标:

  如果图标不对的话,请检查一下你的WSH有没有安装。它是Windows附件里的一个可选组件。不过默认情况是安装它的。
  双击你得到的文件,怎么样?好玩么?如果你懂VB的话,你一定可以事半功倍学会WSH。
  写个大工程——安装程序。许多人都知道,编写安装程序是很麻烦的。不过使用WSH,2KB的文件就可以发挥很大的作用。需要注意一点,WSH不提供Shell语句,因此要调用其它程序,需要使用Shell对象。详情请见第一行。还有建立文件夹的命令我没找到,我使用了Command.com来建立。如果你发现了,请告诉我。还是先看看吧:
Set myShell = WScript.CreateObject("WScript.Shell")

'打开记事本,显示"许可协议"。如果不需要,这几行可删去
myShell.run "Start.exe license.txt",vbHide
if MsgBox("同意以上许可协议吗?",vbQuestion+vbYesNo,"安装")=vbNo Then
    WScript.Quit
end if

'可以修改这一行,改变默认安装路径
myPath="C:\BabyFox"

do
    myPath=InputBox("请输入安装路径","安装",myPath)

    if myPath="" then
        myPath="C:\BabyFox"
    end if

    while right(myPath,1)="\"
        myPath=left(myPath,len(myPath)-1)
    wend

    '判断路径名是否合法
    If InStr(myPath, "/") <> 0 Then Warn=1
    If InStr(myPath, "*") <> 0 Then Warn=1
    If InStr(myPath, "?") <> 0 Then Warn=1
    If InStr(myPath, chr(34)) <> 0 Then Warn=1
    If InStr(myPath, "<") <> 0 Then Warn=1
    If InStr(myPath, ">") <> 0 Then Warn=1
    If InStr(myPath, "|") <> 0 Then Warn=1

    if Warn=1 then
        MsgBox "路径不合法!请重新输入!",vbExclamation,"安装"
        Warn=0
        answer=vbYes
    else
        answer=MsgBox("安装到 " & myPath & ",以上设置需要改变吗?",vbQuestion+vbYesNoCancel,"安装")
    end if
loop until answer<>vbYes

if answer=vbCancel then
    WScript.Quit
end if

myShell.run "Command.com /C md " & chr(34) & myPath & chr(34),vbHide

'可以使用其它格式的压缩包、解压程序,或直接使用WinZip自解压EXE
myShell.run "Extract.exe /E /Y /L " & chr(34) & myPath & chr(34) & " Setup.cab",vbHide

if MsgBox("要在桌面上创建本程序的快捷方式吗?",vbQuestion+vbYesNo,"安装")=vbYes Then
    '重点来了!WSH创建快捷方式的功能强大得让你咋舌
    Desktop = myShell.SpecialFolders("Desktop")

    '将这行改为你的软件的名称
    Set MyShortcut=myShell.CreateShortcut(Desktop & "\狐崽软件.lnk")

    '将这几行改为你的软件的有关信息
    MyShortcut.TargetPath=myPath & "\Test.exe"
    MyShortcut.WorkingDirectory=myPath
    MyShortcut.WindowStyle=4
    MyShortcut.IconLocation=myPath & "\Test.exe,0"
    MyShortcut.Save
end if

'这行也可以按你的需要修改
MsgBox "安装完成,谢谢使用。请与我联系:" & chr(13) & chr(10) & "    edyfox@btamail.net.cn",vbInformation,"安装"
  怎么样?好用吗?与我联系哟!